_

[LISP] CADPL-Pack-v1.lsp [Dyskusja]

Forum poświęcone flagowemu produktowi oraz aplikacjom pochodnym Autodesku. To jedyne forum mające w tytule nazwę programu, a to ze względu na jego olbrzymią popularność w Polsce. Można tutaj umieszczać również posty z ogólnie pojętej tematyki "Kreślarskie 2D".

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez ziele_o2k » mar 09, 2018 10:43

kruuger napisał(a):
ziele_o2k napisał(a):chm coś nie chce działać.
20180308_0058.jpg

zapisz na dysk i dopiero otworz plik. nie otwieraj z przegladarki.
k.

Niestety nie działa u mnie, ale jeszcze zobaczę.

Wracając do tematu CADPL-Packa to:
  1. http://forum.cad.pl/cadpl-pack-v1-lsp-t78158-1440.html#p7738155
    Kod: Zaznacz cały
    cd:SYS_GetFonts
  2. http://forum.cad.pl/cadpack-propozycja-dcl-stdquickoptionsdialog-t111618.html
    Kod: Zaznacz cały
    cd:DCL_StdQuickOptionsDialog
    - tutaj jedna uwaga, okazuj się, że nawet dla mnie - autora, to jest zbyt skomplikowane i jak już się człowiek wprawił w pisaniu dclów, to szyciej napisać dedykowane niż, dynamiczne, ale bardzo często używam cd:DCL_CheckEditBoxValue, które wyciągnąłem na zewnątrz z cd:DCL_StdEditBoxDialog, więc może chociaż to podkręcimy ?
  3. http://forum.cad.pl/czytanie-i-zapis-plikow-ini-t110877.html
    Kod: Zaznacz cały
    pz:INI-Get
    pz:INI-Set
    pz:INI-Del

    Poza ostatnim błędem wyłapanym przez Prezesa kruugera, jeszcze jedna rzecz mi tam się sypała, ale wydaje mi się, że warto dopracować.
  4. Kiedyś gdzieś coś pisałem, że MakeBlock coś nie działa z łapaniem wymiarów - może poprawić ?
  5. Tutaj propozycja, musiałem coś takiego napisać, bo chińczyk nie miał fnsplitl, a poza tym moje pz:fnsplitl działa szybciej niż autocadowe:
    Kod: Zaznacz cały
    (defun pz:fnsplitl ( @fn / _str_lst _res _p1 _p2 _1st_elm _str_lst  )
      (setq _str_lst (vl-string->list @fn))
      (if (member 47 _str_lst)
        (setq
          @fn (vl-string-translate "/" "\\" @fn)
          _str_lst (vl-string->list @fn)
        )
      )
      (cond
        ( (or
            (= (last _str_lst) 92)
            (= (car  _str_lst) 46)
            (= @fn "")
          )
          (setq _res nil)
        )
        ( (setq _p1 (vl-string-position 92 @fn nil t))
          (setq _1st_elm (substr @fn 1 (1+ _p1)))
          (if (and (setq _p2 (vl-string-position 46 @fn nil t)) (< _p1 _p2))
            (setq _res
              (list
                _1st_elm
                (substr @fn (+ 2 _p1) (- _p2 _p1 1))
                (substr @fn (1+ _p2))
              )
            )
            (setq _res
              (list
                _1st_elm
                (substr @fn (+ 2 _p1))
                ""
              )
            )
          )
        )
        ( T
          (if (setq _p2 (vl-string-position 46 @fn nil t))
            (setq _res
              (list
                ""
                (substr @fn 1 (- _p2 1))
                (substr @fn (1+ _p2))
              )
            )
            (setq _res
              (list
                ""
                @fn
                ""
              )
            )
          )
        )
      )
      _res
    )
Ziele
Avatar użytkownika
ziele_o2k
 
Posty: 736
Dołączył(a): mar 18, 2014 11:33
Lokalizacja: Poznań

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez kruuger » mar 09, 2018 10:57

ziele_o2k napisał(a):Niestety nie działa u mnie, ale jeszcze zobaczę.

Wracając do tematu CADPL-Packa to:

win czesto przy otwieraniu pyta czy zawsze otwierac taki pliki, trzebe to odznaczyc. jest czesto problem z tym. win probouje blokowac zawartosc tegoz.

1.Wrzucilem do pack
ACX_AddViewport, SYS_GetFonts, USR_GetCorners, zarowno do cad.lsp jak i pomocy. mozecie rzucic okiem jeszcze.
2. Cza by znowu w to zajrzec
3. To jest trudne do ogarniecie. czytanie-i-zapis-plikow-ini-t110877.html#p7736858 jedna spacja wiecej moze popsuc wszystko.
4. Ze sie nie dodaja do bloku? Cza zmienic ustawienia w MBO
5. Cza by sprawdzic
Avatar użytkownika
kruuger
 
Posty: 4840
Dołączył(a): paź 27, 2005 20:14
Lokalizacja: Kraków

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez ziele_o2k » mar 16, 2018 16:31

  1. Śmiga
  2. Jeśli o to chodzi, to jedynie cd:DCL_CheckEditBoxValue bym wyciągnął. Przygotuję przykład i pokażę co i jak. Używam tego często i przydałoby się mieć w packu.
  3. Nie jest trudne :p ja znalazłem poza tym jeszcze jeden błąd. Jak poprawie to podrzucę.
  4. Działa
  5. Podrzucę przykłady
Ostatnio edytowany przez ziele_o2k mar 18, 2018 03:59, edytowano w sumie 2 razy
Ziele
Avatar użytkownika
ziele_o2k
 
Posty: 736
Dołączył(a): mar 18, 2014 11:33
Lokalizacja: Poznań

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez ziele_o2k » mar 18, 2018 03:47

A takie coś:
Kod: Zaznacz cały
(defun cd:SYS_DecSep ()
  (or
    *cd-DecimalSeparator*
    (setq *cd-DecimalSeparator*
      (vl-registry-read "HKEY_CURRENT_USER\\Control Panel\\International" "sDecimal")
    )
  )
  *cd-DecimalSeparator*
)
Ziele
Avatar użytkownika
ziele_o2k
 
Posty: 736
Dołączył(a): mar 18, 2014 11:33
Lokalizacja: Poznań

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez kojacek » mar 18, 2018 16:05

ziele_o2k napisał(a):A takie coś:
Kod: Zaznacz cały
(defun cd:SYS_DecSep ()
  (or
    *cd-DecimalSeparator*
    (setq *cd-DecimalSeparator*
      (vl-registry-read "HKEY_CURRENT_USER\\Control Panel\\International" "sDecimal")
    )
  )
  *cd-DecimalSeparator*
)

Ok, ale... dlaczego od razu jako zmienna globalna? Może wystarczyłoby tylko:
Kod: Zaznacz cały
(defun cd:SYS_DecSep ()
  (vl-registry-read "HKEY_CURRENT_USER\\Control Panel\\International" "sDecimal")
)

Wtedy przecież zawsze możesz ją wywołać przypisując, albo do global, albo do lokal. W zależności co uznasz za konieczne.
Avatar użytkownika
kojacek
 
Posty: 5453
Dołączył(a): paź 03, 2005 20:17

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez ziele_o2k » mar 18, 2018 17:27

W sumie racja. Na tyle sporadycznie będzie używane, że można tak podejść.

EDIT: nie było pytania - ten wątek nie od tego!
Ziele
Avatar użytkownika
ziele_o2k
 
Posty: 736
Dołączył(a): mar 18, 2014 11:33
Lokalizacja: Poznań

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez ziele_o2k » mar 18, 2018 17:37

Tak za pamięci, bo ostatnio mi się wróciło to textboxów:
http://forum.cad.pl/post7708999.html?hilit=textbox#p7708993
Kod: Zaznacz cały
; =========================================================================================== ;
;  DATA  [LIST] - An entity definition list defining a text object,                           ;
;                 in the format returned by entget                                            ;
;  Mode [T/nil] - nil = standard textbox function procedure                                   ;
;                       (ignore spaces at start and end of string)                            ;
;                 T   = extended textbox function                                             ;
;                       (do not ignore spaces at start and end of string)                     ;
; =========================================================================================== ;
(defun TextBoxExt (Data Mode / _SpacesI _SpaceLen s i e r)
  (setq s (cdr (assoc 1 Data)) r (textbox Data))
  (defun _SpacesI (s / l)
    (-
      (strlen s)
      (strlen (vl-string-trim " " s))
    )
  )
  (defun _SpaceLen (d)
    (-
      (caadr (textbox (subst (cons 1 "A A")(assoc 1 d) d)))
      (caadr (textbox (subst (cons 1 "AA")(assoc 1 d) d)))
    )
  )
  (if Mode
    (if
      (wcmatch s " *,* ")
      (progn
        (setq i (_SpacesI s) e (_SpaceLen Data))
        (list
          (car r)
          (list
            (+ (caadr r) (* e i))
            (cadr (cadr r))
            (caddr (cadr r))
          )
        )
      )
      r
    )
    r
  )
)

a tutaj wersja LeeMaca, jeszcze ładniejsza niż moja:
Kod: Zaznacz cały
; =========================================================================================== ;
;  enx   [LIST] - An entity definition list defining a text object,                           ;
;                 in the format returned by entget                                            ;
;  flg  [T/nil] - nil = standard textbox function procedure                                   ;
;                       (ignore spaces at start and end of string)                            ;
;                 T   = extended textbox function                                             ;
;                       (do not ignore spaces at start and end of string)                     ;
; =========================================================================================== ;

(defun TextBoxExt ( enx flg / textboxs )
  (defun textboxs ( enx str )
    (textbox (subst (cons 1 str) (assoc 1 enx) enx))
  )
  (if
    (and flg (wcmatch (cdr (assoc 1 enx)) " *,* "))
    (
      (lambda ( a b ) (list (car a) (cons (- (caadr a) (caadr b)) (cdadr a))))
      (textboxs enx (strcat "-" (cdr (assoc 1 enx)) "-"))
      (textboxs enx "--")
    )
    (textbox enx)
  )
)
Ziele
Avatar użytkownika
ziele_o2k
 
Posty: 736
Dołączył(a): mar 18, 2014 11:33
Lokalizacja: Poznań

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez kruuger » mar 19, 2018 10:12

ogarnia ktos jakies platformy jak github itp? gdzie by mozna pracowac wspolnie nad plikiem CadPack'a ?
jedynie ze jakis inny pomysl macie? moze cos w chmurze do kolaboracji ?
z helpem tez zawsze jest sporo roboty. tez mozna by to jakos szerować.
k.
Avatar użytkownika
kruuger
 
Posty: 4840
Dołączył(a): paź 27, 2005 20:14
Lokalizacja: Kraków

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez ziele_o2k » mar 19, 2018 11:02

kruuger napisał(a):ogarnia ktos jakies platformy jak github itp? gdzie by mozna pracowac wspolnie nad plikiem CadPack'a ?
jedynie ze jakis inny pomysl macie? moze cos w chmurze do kolaboracji ?
z helpem tez zawsze jest sporo roboty. tez mozna by to jakos szerować.
k.

Ja obiecuję od jakiegoś czasu, że podzielę się swoimi dyrdymałami, ale nie mam czasu na założenie stronki więc założyłem konto na githubie tydzień temu i powolutku zaczynam ogarniać. Muszę przerobić wszystko na wersję dwujęzykową i powoli będę udostępniać.

Generalnie, myślę że warto przerzucić się na githuba.
Ziele
Avatar użytkownika
ziele_o2k
 
Posty: 736
Dołączył(a): mar 18, 2014 11:33
Lokalizacja: Poznań

Re: [LISP] CADPL-Pack-v1.lsp [Dyskusja]

Postprzez kruuger » mar 19, 2018 11:15

ziele_o2k napisał(a):
kruuger napisał(a):ogarnia ktos jakies platformy jak github itp? gdzie by mozna pracowac wspolnie nad plikiem CadPack'a ?
jedynie ze jakis inny pomysl macie? moze cos w chmurze do kolaboracji ?
z helpem tez zawsze jest sporo roboty. tez mozna by to jakos szerować.
k.

Ja obiecuję od jakiegoś czasu, że podzielę się swoimi dyrdymałami, ale nie mam czasu na założenie stronki więc założyłem konto na githubie tydzień temu i powolutku zaczynam ogarniać. Muszę przerobić wszystko na wersję dwujęzykową i powoli będę udostępniać.

Generalnie, myślę że warto przerzucić się na githuba.

to sie ma jakies konto czy jakis konkretny projekt?
podaj linka jak juz masz cos. moze bedzie sie latwiej w to wgrysc jak bedzie mniej rzeczy poki co.
k.
Avatar użytkownika
kruuger
 
Posty: 4840
Dołączył(a): paź 27, 2005 20:14
Lokalizacja: Kraków

Poprzednia stronaNastępna strona

Powrót do AutoCAD

Kto przegląda forum

Użytkownicy przeglądający ten dział: Brak zidentyfikowanych użytkowników